'---------------------------------------------------------------------------
'   PARAMETROS

'   Nombre de la Escala
%Lab=<A
'   Centro
%Cx==105
%Cy==140
'    Radio de la escala
%Rad==90
'Angulo de inicio en referencia a la vertical
%Ang==0
'     Décadas
%Dec ==1
' Primer Valor
%Val == 1
'Orden Inverso
%Rev==0
'Font Numeros
%Fnt = Arial
'Inversion (1 = ticks por dentro)
%Inv ==0
'Tipo de Arco
%Arc==1
'Largos de los ticks
%T1==5   '1
%T2==4    '.5
%T3==3    '.1
%T4==2    '.05
%T5==1.5    '.02 y.01
'Espesores de los ticks
%E1==6
%E2==5
%E3==4
%E4==3
%E5==1
'Color del Fondo
%Bck=RVB  255 201 255

'--------------------------------------------------------------------
ZoomIni = 1
Police = %Fnt
CentreE = %Cx, %Cy, bleu
CentreI = %Cx, %Cy, bleu

'Background
%wid==%T3*25
EpaisT=%wid
If %Inv=1 goto B1
Arc=0,360,%Rad+%T3/2,%Bck
Goto Be
B1:
Arc=0,360,%Rad-%T3/2,%Bck
Be:
EpaisT= 1

If %Rev=0 goto A1
  If %Arc = 0 then Arc = 90+%Ang, -270+%Ang, %Rad,white
  If %Arc = 1 then Arc = 90+%Ang, -270+%Ang, %Rad,black
  If %Arc <=1 goto A0
     If %Inv=1 then Arc = 90+%Ang, -270+%Ang, %Rad-%T5, black
     If %Inv=0 then Arc = 90+%Ang, -270+%Ang, %Rad+%T5, black
  Arc = 90+%Ang, -270+%Ang, %Rad, black
A0:
Goto Aend 

A1:
  If %Arc = 0 then Arc = 90+%Ang, 450+%Ang, %Rad,white
  If %Arc = 1 then Arc = 90+%Ang, 450+%Ang, %Rad,black
  If %Arc <=1 goto Aend
     If %Inv=1 then Arc = 90+%Ang, 450+%Ang, %Rad-%T5, black
     If %Inv=0 then Arc = 90+%Ang, 450+%Ang, %Rad+%T5, black
   Arc = 90+%Ang, 450+%Ang, %Rad,black
Aend:

Exposant = L, %Dec

If %inv=1 then Inversion

' Tickmarks
'--------------------------------------------------------
If %Dec>1 goto D2
Grad = .01§2,%T5,,,%E5
Grad = .02§5§2,%T5,,,%E5
Grad =.05§2§1,%T4,,,%E4
Grad =.05§10§5,%T4,,,%E4
Goto Dx

D2:
If %Dec>2 goto D3
Grad = .02§5,%T5,,,%E5
Grad =.05§7§5,%T4,,,%E4
Goto Dx

D3:
Grad = .02§3,%T5,,,%E5
Grad =.05§5§3,%T4,,,%E4

Dx:
Grad = .1,%T3,,,%E3
Grad = .5§10§2,%T2,,,%E2


'Index
'Grad = 1,%T1,,,%E1


' Labels
'------------------------------------------------------------
If %Dec>1 goto L2
TailleP = *.65g
ValR=0,0.1§2,%Val,,(%T3+1),1.1,1.9
Goto Lx
L2:
If %Dec>2 goto L3
TailleP = *.65g
ValR=0,0.2§2,%Val,,(%T3+1),1.1,1.9
ValR=0,0.2§2,%Val,,(%T3+1),11,19
Goto Lx
L3:
TailleP = *.65g
'ValR=0,0.5§2,%Val,,(%T3+2),1.1,1.9
Lx:
TailleP = *0.8g
ValR=0,1,%Val,,(%T1+0),,9.9*10^(%Dec-1)

'Scale Label & Index Mark
'-----------------------------------------------------------
Grad1=1,(%T3),,white
If %Inv=1 goto Lab1
  %px=(%rad+%T3)*cos(90-%Ang),%px(1)+2.83*cos(135-%Ang),%px(2)+2*cos(90-%Ang),%px(3)+4*cos(-%Ang),%px(4)+2*cos(270-%Ang),%px(5)+2.83*cos(225-%Ang)
  %py=(%rad+%T3)*sin(90-%Ang),%py(1)+2.83*sin(135-%Ang),%py(2)+2*sin(90-%Ang),%py(3)+4*sin(-%Ang),%py(4)+2*sin(270-%Ang),%py(5)+2.83*sin(225-%Ang)

   PolyP=black,%px(1),%py(1),%px(2),%py(2),%px(3),%py(3),%px(4),%py(4),%px(5),%py(5),%px(6),%py(6)
   TexteC=0r,0r,%Rad+4.6,90+%Ang,white,BX,%Lab
   Goto LabEnd

Lab1:
   %px=(%rad-%T3)*cos(90-%Ang),%px(1)+2.83*cos(-45-%Ang),%px(2)+2*cos(-90-%Ang),%px(3)+4*cos(180-%Ang),%px(4)+2*cos(90-%Ang),%px(5)+2.83*cos(45-%Ang)
   %py=(%rad-%T3)*sin(90-%Ang),%py(1)+2.83*sin(-45-%Ang),%py(2)+2*sin(-90-%Ang),%py(3)+4*sin(180-%Ang),%py(4)+2*sin(90-%Ang),%py(5)+2.83*sin(45-%Ang)

    PolyP=black,%px(1),%py(1),%px(2),%py(2),%px(3),%py(3),%px(4),%py(4),%px(5),%py(5),%px(6),%py(6)
    TexteC=0r,0r,%Rad-6.4,90+%Ang,white,BX,%Lab
LabEnd:
Grad1=1,(%T3)